When distributing reports that contain live links or links to WebFOCUS reports (drill downs), the URL context must be fully qualified and the user must have connectivity to the Web/Application server in order to run the report or access the content of the link. You can fully qualify the live link using the SET FOCHTMLURL or SET BASEURL commands. Use SET FOCHTMLURL to access resources that reside under the ibi_html alias. For non-Managed Reporting procedures, use SET BASEURL to specify a default location for a relative URL that references documents (HTML files, images, Java files) created by WebFOCUS. You can fully qualify the drill down using the SET FOCEXURL command.

To drill-down to a WebFOCUS Reporting Server procedure, the original procedure you are scheduling must include the following command:

SET FOCEXURL=http://hostname[:port]/wf_context_root/WFServlet;

where:

hostname[:port]

Is the host name and optional port number of the Web/Application Server on which the WebFOCUS Client is installed.

wf_context_root

Is the site-customized context root for the WebFOCUS Web application deployed on your Application Server. ibi_apps is the default value.

The following shows an example of the FOCEXURL command in a FEX.

-* FEX that is scheduled and distributed to the Report Library
-* Set FOCEXURL value for navigation back to WF Client and MR context
-* for execution of drill down request.  Must be coded using
-* concatenation of so that WF describe (auto prompting) is not invoked 
-* and also for character encoding within URL to be done correctly.
-* Protocol, host and port to WF client.  
-* Do not use localhost for the host value!
-SET &FOCEXURL='http://host:port';
-*
-* Call to WF Client.  /ibi_apps is the default URL context 
-* but can be customized
-SET &FOCEXURL=&FOCEXURL | '/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps'  '&';
-* If report contains a drilldown the next set of lines are also needed.
-* Set WF Reporting Server to run request on
-SET &FOCEXURL=&FOCEXURL | 'IBIC_server=EDASERVE' | '&';
-*
-* Set whether the message viewer feature is ON or OFF.
-* When message viewer feature is ON the browser window displaying the 
-* report will have multiple frames.  The top frame displays 
-* the report and the bottom frame displays any messages returned 
-* from the WF Server from the report execution.
-* Most often utilized during report development or to debug a problem.
-SET &FOCEXURL=&FOCEXURL | 'IBIWF_msgviewer=OFF' | '&';
-*
-* IBIMR_drill tells WF client subsequent request is a drill down and the 
-* information after X, is the HREF of the MR domain that the 
-* drill down FEX
-* is located in.  In this example 'salesrpt' is the internal 
-* domain directory and salesrpt.htm is the HTML file 
-* containing the metadata information for the contents
-* within the salesrpt domain.
-SET &FOCEXURL=&FOCEXURL | 'IBIMR_drill=X,salesrpt/salesrpt.htm'| '&';
-*
-* SET environmental variable FOCEXURL

SET FOCEXURL='&FOCEXURL'
-*
TABLE FILE CAR
SUM CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=CAR.ORIGIN.COUNTRY,
 FOCEXEC=salesrpt/app/carmodel.fex,
 $
ENDSTYLE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END

The following is an example of the drill down FEX that resides in Managed Reporting.

-* HTML Tool
-* Created by Report Assistant
-* FF Line do not change this line! Field Name
-* FF Line do not change this line! Alias
-* FF Line do not change this line! Format
-* FF Line do not change this line! Segment
-* FF Line do not change this line! displayTree=0
TABLE FILE CAR
SUM CAR.SPECS.MPG
CAR.SPECS.RPM
CAR.BODY.SEATS
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
BY CAR.BODY.BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END
-* End Report Assistant